Submission #2502759

---

Source Code Expand

/+ dub.sdl:
    name "F"
    dependency "dunkelheit" version=">=0.9.0"
+/

import std.stdio, std.algorithm, std.range, std.conv;
// import dkh.foundation, dkh.scanner;

int solve(int[][] g, bool[] s) {
    int n = g.length.to!int;

    foreach (i; 0..n) {
        if (g[i].length % 2) s[i] = !s[i];
    }

    debug {
        foreach (v; g) {
            writeln(v);
        }
        writeln(s);
    }

    int base = 0;
    base += 2*(n-1) + s.count(true).to!int;

    int ans = 0;
    int dfs(int p, int b) {
        int[2] buf = [0, 0];
        foreach (d; g[p]) {
            if (d == b) continue;
            int ch = dfs(d, p);
            if (ch > buf[0]) swap(ch, buf[0]);
            if (ch > buf[1]) swap(ch, buf[1]);
        }
        if (s[p]) {
            if (g[p].length.to!int == 1) {
                buf[0]++;
            } else {
                buf[0] += 2;
            }
        }
        ans = max(ans, buf[0] + buf[1]);
        return buf[0];
    }
    dfs(0, -1);
    debug writeln("ANS! ", base, " ", ans);

    return base - ans;
}


int main() {
    Scanner sc = new Scanner(stdin);
    scope(exit) assert(!sc.hasNext);

    int n;
    sc.read(n);
    int[][] g = new int[][n];
    foreach (i; 0..n-1) {
        int a, b; sc.read(a, b); a--; b--;
        g[a] ~= b; g[b] ~= a;
    }
    string s;
    sc.read(s);

    int wc = s.count('W').to!int;
    if (wc == 0) {
        writeln(0);
        return 0;
    } else if (wc == 1) {
        writeln(1);
        return 0;
    }

    int[] wsz = new int[n];
    bool[] enable = new bool[n];
    void dfs(int p, int b) {
        wsz[p] = 0;
        int chv = 0;
        if (s[p] == 'W') {
            wsz[p] = 1;
            chv = 2;
        }
        foreach (d; g[p]) {
            if (d == b) continue;
            dfs(d, p);
            wsz[p] += wsz[d];
            if (wsz[d]) chv++;
        }
        if (wsz[p] != wc) {
            chv++;
        }
        enable[p] = (chv >= 2);
    }
    dfs(0, -1);

    int n2 = enable.count(true).to!int;
    int[] newID = new int[n]; int idc = 0;
    bool[] s2 = new bool[n2];
    foreach (i; 0..n) {
        if (enable[i]) {
            newID[i] = idc++;
            s2[newID[i]] = (s[i] == 'W');
        }
    }

    int[][] ng = new int[][n2];
    foreach (i; 0..n) {
        if (!enable[i]) continue;
        foreach (j; g[i]) {
            if (i > j || !enable[j]) continue;
            ng[newID[i]] ~= newID[j];
            ng[newID[j]] ~= newID[i];
        }
    }

    writeln(solve(ng, s2));
    return 0;
}
/* IMPORT /home/yosupo/Program/dunkelheit/source/dkh/container/stackpayload.d */
// module dkh.container.stackpayload;

 
struct StackPayload(T, size_t MINCAP = 4) if (MINCAP >= 1) {
    import core.exception : RangeError;

    private T* _data;
    private uint len, cap;

    @property bool empty() const { return len == 0; }
    @property size_t length() const { return len; }
    alias opDollar = length;

     
    inout(T)[] data() inout { return (_data) ? _data[0..len] : null; }
    
    ref inout(T) opIndex(size_t i) inout {
        version(assert) if (len <= i) throw new RangeError();
        return _data[i];
    }  
    ref inout(T) front() inout { return this[0]; }  
    ref inout(T) back() inout { return this[$-1]; }  

    void reserve(size_t newCap) {
        import core.memory : GC;
        import core.stdc.string : memcpy;
        import std.conv : to;
        if (newCap <= cap) return;
        void* newData = GC.malloc(newCap * T.sizeof);
        cap = newCap.to!uint;
        if (len) memcpy(newData, _data, len * T.sizeof);
        _data = cast(T*)(newData);
    }  
    void free() {
        import core.memory : GC;
        GC.free(_data);
    }  
     
    void clear() {
        len = 0;
    }

    void insertBack(T item) {
        import std.algorithm : max;
        if (len == cap) reserve(max(cap * 2, MINCAP));
        _data[len++] = item;
    }  
    alias opOpAssign(string op : "~") = insertBack;  
    void removeBack() {
        assert(!empty, "StackPayload.removeBack: Stack is empty");
        len--;
    }  
}

 
/* IMPORT /home/yosupo/Program/dunkelheit/source/dkh/foundation.d */
 
// module dkh.foundation;

 
static if (__VERSION__ <= 2070) {
    /*
    Copied by https://github.com/dlang/phobos/blob/master/std/algorithm/iteration.d
    Copyright: Andrei Alexandrescu 2008-.
    License: $(HTTP boost.org/LICENSE_1_0.txt, Boost License 1.0).
    */
    template fold(fun...) if (fun.length >= 1) {
        auto fold(R, S...)(R r, S seed) {
            import std.algorithm : reduce;
            static if (S.length < 2) {
                return reduce!fun(seed, r);
            } else {
                import std.typecons : tuple;
                return reduce!fun(tuple(seed), r);
            }
        }
    }
     
}
/* IMPORT /home/yosupo/Program/dunkelheit/source/dkh/scanner.d */
// module dkh.scanner;

// import dkh.container.stackpayload;

 
class Scanner {
    import std.stdio : File;
    import std.conv : to;
    import std.range : front, popFront, array, ElementType;
    import std.array : split;
    import std.traits : isSomeChar, isStaticArray, isArray; 
    import std.algorithm : map;
    File f;
    this(File f) {
        this.f = f;
    }
    char[512] lineBuf;
    char[] line;
    private bool succW() {
        import std.range.primitives : empty, front, popFront;
        import std.ascii : isWhite;
        while (!line.empty && line.front.isWhite) {
            line.popFront;
        }
        return !line.empty;
    }
    private bool succ() {
        import std.range.primitives : empty, front, popFront;
        import std.ascii : isWhite;
        while (true) {
            while (!line.empty && line.front.isWhite) {
                line.popFront;
            }
            if (!line.empty) break;
            line = lineBuf[];
            f.readln(line);
            if (!line.length) return false;
        }
        return true;
    }

    private bool readSingle(T)(ref T x) {
        import std.algorithm : findSplitBefore;
        import std.string : strip;
        import std.conv : parse;
        if (!succ()) return false;
        static if (isArray!T) {
            alias E = ElementType!T;
            static if (isSomeChar!E) {
                 
                 
                auto r = line.findSplitBefore(" ");
                x = r[0].strip.dup;
                line = r[1];
            } else static if (isStaticArray!T) {
                foreach (i; 0..T.length) {
                    bool f = succW();
                    assert(f);
                    x[i] = line.parse!E;
                }
            } else {
                StackPayload!E buf;
                while (succW()) {
                    buf ~= line.parse!E;
                }
                x = buf.data;
            }
        } else {
            x = line.parse!T;
        }
        return true;
    }

    int unsafeRead(T, Args...)(ref T x, auto ref Args args) {
        if (!readSingle(x)) return 0;
        static if (args.length == 0) {
            return 1;
        } else {
            return 1 + read(args);
        }
    }
    void read(Args...)(auto ref Args args) {
        import std.exception;
        static if (args.length != 0) {
            enforce(readSingle(args[0]));
            read(args[1..$]);
        }
    }
    bool hasNext() {
        return succ();
    }
}


 
 

 

/*
This source code generated by dunkelheit and include dunkelheit's source code.
dunkelheit's Copyright: Copyright (c) 2016- Kohei Morita. (https://github.com/yosupo06/dunkelheit)
dunkelheit's License: MIT License(https://github.com/yosupo06/dunkelheit/blob/master/LICENSE.txt)
*/

Submission Info

Judge Result